dateinperiod con dos campos de fecha diferentes (SUMIFS Exclel) no funciona

Hola Ruud_K ,

«

Ahora quiero calcular cuánto trabajo puedo esperar durante los próximos 56 días para una ubicación y un producto, o en general.

Quiero calcular la cantidad de tiempo [Time service] por [Created date] igual o anterior a cualquier fecha elegida y para [Plan delivery date] en los próximos 56 días a partir de la fecha elegida.

«

<--- ¿Qué relación entre la tabla de fechas y la tabla de reservas, podría aclarar más detalles sobre su resultado esperado?

Saludos,

Jimmy Tao

Hola jimmy

En realidad, es muy simple.

Tengo los dos campos de fecha vinculados a mi tabla de fecha.

El enlace para [Plan delivery date] está activo. El otro inactivo ya que solo puedo elegir una relación activa.

Los resultados esperados y las fórmulas de Excel son los siguientes:

Quiero calcular la cantidad de tiempo [Time service] por [Created date] igual o anterior a cualquier fecha elegida y para [Plan delivery date] en los próximos 56 días a partir de la fecha elegida.

esto debería funcionar después de claryfing de dónde viene ‘cualquier fecha elegida’, ahora está codificado a 2018-03-15 en la variable SelectedDate. ¿Se supone que proviene de la fecha de entrega del plan? las fechas en su ejemplo de Excel no coinciden con él

Measure =
VAR SelectedDate =
    DATE ( 2018, 3, 15 )
VAR Workload =
    FILTER (
        'Table',
        'Table'[Plan delivery Date]
            < SelectedDate + 56
            && 'Table'[Plan delivery Date] >= SelectedDate
            && 'Table'[Created date] <= SelectedDate
    )
RETURN
    SUMX ( Workload, [Time service] )

La fecha proviene de una tabla de dimensiones de 2010 a 2099 llamada Fecha en la fecha del nombre del campo (Fecha[Date])

Gracias por la entrada.

La fórmula está funcionando pero no da los resultados correctos.

Para aclarar.

Me gustaría hacer un vusual donde pueda mostrar la carga de trabajo planificada conocida durante un período de tiempo de, digamos, 16 meses.

Esto significa la suma de los valores [Time_service] para todos los [Created_Date] igual o mayor que 2016; 2; 16 y todos los [Plan_Delivery_Date] igual o 56 días después de 2016; 2; 16.

He usado la siguiente fórmula:

Measure 3 = VAR SelectedDate =
DATE (2016;2;16)
VAR Workload =
    FILTER (
        'Reservations';
        'Reservations'[Plan_Delivery_Date]
            < SelectedDate + 56
            && 'Reservations'[Plan_Delivery_Date] >= SelectedDate
            && 'Reservations'[Created_Date] <= SelectedDate     )
RETURN
    SUMX ( Workload; [Time_service] )

Mi modelo de datos es el siguiente:

Los resultados de la fórmula no coinciden con los valores esperados.

¿Qué necesito alterar en el Fórmula DAX.

PD. Preferiría una fórmula en la que se usa Dat_Dim en lugar de una fecha fija. Como quiero una visualización en más de 1 fecha

Hola @Stachu

Funciona perfectamente. Gracias por esto.

¿Podría molestar a alguien con una pregunta adicional sobre este problema?

¿Es posible obtener los valores, pero no durante 56 días intermedios, sino durante 40 días laborables?

La tabla de fechas tiene un indicador de día laborable (J / N) llamado [Workday_ind] y un valor de Workdat (1 o 0) denominado [Workday_value]

prueba esto, puedes jugar con > =/> para conseguir exactamente lo que necesitas

Measure 3 = 
VAR SelectedDate = SELECTEDVALUE(Date_Dim[Date])
VAR OnlyWorking = FILTER(ALL(Date_Dim[Date], Date_Dim[Workday_value]), Date_Dim[Workday_value]<>0 && Date_Dim[Date]>SelectedDate)
VAR RollingWD = ADDCOLUMNS(OnlyWorking,"RollingWD",RANKX(OnlyWorking, [Date], ,ASC))
VAR NextDate = CALCULATE(MAX(Date_Dim[Date]),FILTER(RollingWD,[RollingWD]=40))
VAR Workload =
    FILTER (
        'Reservations',
        'Reservations'[Plan_Delivery_Date]
            <= NextDate
            && 'Reservations'[Plan_Delivery_Date] >= SelectedDate
            && 'Reservations'[Created_Date] <= SelectedDate
    )
RETURN
    SUMX ( Workload, [Time_service] )

EDITAR
esto puede funcionar incluso mejor:

Measure 3 = 
VAR SelectedDate = SELECTEDVALUE(Date_Dim[Date])
VAR OnlyWorking = FILTER(ALL(Date_Dim[Date], Date_Dim[Workday_value]), Date_Dim[Workday_value]<>0 && Date_Dim[Date]>SelectedDate)
VAR Top40WD = TOPN(40,OnlyWorking,[Date],ASC)
VAR NextDate = CALCULATE(MAX(Date_Dim[Date]),Top40WD)
VAR Workload =
    FILTER (
        'Reservations',
        'Reservations'[Plan_Delivery_Date]
            < NextDate
            && 'Reservations'[Plan_Delivery_Date] >= SelectedDate
            && 'Reservations'[Created_Date] <= SelectedDate
    )
RETURN
    SUMX ( Workload, [Time_service] )