Cómo comparar los números de versión en DAX

Guión:

Suponga que algunos clientes están ejecutando versiones de software demasiado antiguas y necesita encontrarlas antes de actualizar.

Cómo lograr eso:

Data de muestra

Consejos:

• Utilice SUBSTITUTE y PATHITEM para dividir los números de versión

https://docs.microsoft.com/en-us/dax/substitute-function-dax

https://docs.microsoft.com/en-us/dax/pathitem-function-dax

• Utilice ISAFTER para obtener la lista final

Pasos:

1. Agregue una medida que contenga el número de versión de destino manualmente

Measure target version = "2.85.20.10" 

2. Agrega una tabla calculada

Table 2 =  

VAR target_version = [Measure target version] 

VAR target_version_path = 

    SUBSTITUTE ( target_version, ".", "|" ) 

VAR target_version_1 = 

    PATHITEM ( target_version_path, 1, INTEGER ) 

VAR target_version_2 = 

    PATHITEM ( target_version_path, 2, INTEGER ) 

VAR target_version_3 = 

    PATHITEM ( target_version_path, 3, INTEGER ) 

VAR target_version_4 = 

    PATHITEM ( target_version_path, 4, INTEGER ) 

RETURN 

    FILTER ( 

        'Table', 

        VAR version_path = 

            SUBSTITUTE ( 'Table'[Version], ".", "|" ) 

        VAR version_1 = 

            PATHITEM ( version_path, 1, INTEGER ) 

        VAR version_2 = 

            PATHITEM ( version_path, 2, INTEGER ) 

        VAR version_3 = 

            PATHITEM ( version_path, 3, INTEGER ) 

        VAR version_4 = 

            PATHITEM ( version_path, 4, INTEGER ) 

        RETURN 

            ISAFTER ( 

                version_1, target_version_1, DESC, 

                version_2, target_version_2, DESC, 

                version_3, target_version_3, DESC, 

                version_4, target_version_4, DESC ) 

    ) 

Ahora, sabe que el cliente B / D / F debe actualizar la versión al menos a «Medir la versión de destino» 2.85.20.10

Consulte el archivo adjunto para obtener más detalles.

Autor: Sam Zha

Revisor: Kerry & Ula